home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Belgian Amiga Club - ADF Collection
/
BS1 part 19.zip
/
BS1 part 19
/
A-talk III release disk 1.adf
/
Scripts
/
pcpursuit.scr
< prev
next >
Wrap
Text File
|
1988-09-30
|
3KB
|
160 lines
# pur001;860825
#
# Generic PC Pursuit dialer script for A-Talk III
#
# with Racal-Vadic call progression
#
# by Jack Radigan
#
# Clear screen and start prompt sequence.
#
CLEAR
ECHO "PC Pursuit dialer."
ECHO ""
#
# User flow control.
#
# This allows you to start another script while still connected to a
# remote modem. It will either dial another number in the same city
# or re-connect to a different city. In addition, it will terminate
# the connection and then hang-up your modem if so desired.
#
ask "Dial Telenet? (y/n)"
IF y GOTO dialmain
ECHO ""
ASK "Disconnect from Telenet? (y/n)"
IF y GOTO hangup
ECHO ""
ASK "Are you connected to a target city? (y/n)"
IF n GOTO dial2
ECHO ""
ASK "Do you need to change cities? (y/n)"
IF n GOTO dial3
#
# Before changing cities, make sure Racal-Vadic mode is disabled.
#
reply "I^M"
delay 10
reply "^M"
delay 5
reply "@"
delay 5
reply "^M"
wait "@"
reply "D^M"
DELAY 1
GOTO dial2
#
# Disable Racal-Vadic mode prior to hanging up local modem.
#
hangup:
reply "I^M"
delay 15
#
# Hayes commands are used for hang-up, change if necessary.
#
reply "+++"
WAIT "OK"
reply "ATH^M"
STOP
#
# Start local modem dial loop.
#
dialmain:
#
# Hayes commands also used here, you must alter this section if your
# modem uses a different command set.
#
reply "ATZ^M"
WAIT "OK"
#
# Local modem dial loop re-entry.
#
dial:
delay 5
#
# Local Telenet access number follows.
#
reply "ATDT0000000^M"
DELAY 1
ON "NECT" GOTO dial1
delay 200
reply "ATH^M"
DELAY 1
GOTO dial
#
# End local modem dial loop, begin Telenet log on sequence.
#
dial1:
delay 5
reply "^M"
delay 5
reply "^M"
WAIT "NAL="
reply "D1^M"
wait "@"
#
# Start area code connect loop.
#
dial2:
#
# Insert area code after the word 'DIAL', then put user ID after comma.
#
reply "C D/CALAN/12,TELENETID^M"
WAIT "D = "
#
# Install your password here.
#
reply "MYPASSWORD^M"
ON "CTED" GOTO dial3
wait "@"
GOTO dial2
#
# Remote modem entry.
#
# The following code prevents the remote modem from going into
# manual answer mode if entered from the last prompt and the remote
# modem is also in Racal-Vadic mode. It must also issue an ATZ
# command to insure that the remote is reset when entered from the
# initial remote connect sequence immediately above.
#
dial3:
reply "I^M"
delay 10
reply "ATZ^M"
delay 10
#
# Activate Racal-Vadic command mode.
#
reply "^E^M"
wait "*"
#
# Remote modem dial loop.
#
dial4:
ECHO "Access1, Los Angeles, 213"
ECHO " "
#
# Put phone number of destination after the letter 'D'.
#
reply "D7433752^M"
ON "NECT" GOTO logon
ON "TURN" GOTO logon
WAIT "USY!"
GOTO dial4
#
# Final logon.
#
# If the destination starts transmitting first, the following two
# replys probably will not be needed. You have to see how it reacts
# after connecting and tailor it to log on properly.
#
logon:
BELL
BELL
BELL
BELL
#
# Your actual logon code starts here.
#